Для чтения 7.7 из 7.7 использовался 1cpp+VFPOLEDB. А из восьмерки как ?

А как читать MD. Или каждый раз построчно анализировать DD?

1сpp можно как-то воткнуть в восьмерку?

Я бы делал так:
Создал бы пустую базу 7.7 со спец конфой.
К этой базе коннектишься через ОЛЕ, в ней загружается 1С++, цепляешься к МДшнику нужной базы клюшек, транслируешь запрос в снеговика, выполняешь запрос в снеговике.

Как более продвинутый вариант - не просто спец-конфу, а какие-то параметры вынести в справочники базы. Но абстрактной структуры метаданных я не вижу - разве что, на конкретной задаче что-нить придумается.
А так - в спецконфе только глобальный модуль, который загружает необходимые ДЛЛки в ПриНачалеРаботыСистемы, да имеет парочку экспортных методов (ПрисоединитьМД(), РаспарситьМетаЗапрос(),...).


Еще более брутальный вариант:
создаешь ОЛЕ77 = Новый(ОЛЕ объект 7.7 нужной базы).
Далее, делаешь так:
ОЛЕ77.ЗагрузитьВнешнююКомпоненту("1с++.длл");   //вот тут не 100% уверен. Но должно сработать, кажется.
ОЛЕ77.глРасшифровка = ОЛЕ77.СоздатьОбъект("ОДБЦРекордСет");
ТекстЗапроса = ОЛЕ77.глРасшифровка.ОбрМетаСКЛ(ТекстМетаЗапроса);

Скорее всего, даже не обязательно ссылку на ОДБЦРекордСет хранить через ОЛЕ77.глРасшифровка, достаточно просто
МетаПарсер = ОЛЕ77.СоздатьОбъект("ОДБЦРекордСет");
ТекстЗапроса = МетаПарсер.ОбрМетаСКЛ(ТекстМетаЗапроса);

Ну вот примерчик

? какая стабильность тебя интересует ?

Врят ли, запросов "на полчаса не имею", поэтому таких проблем не было.
А вот оле страдает 2-х минутным таймаутом..

оле да, после 2-х минут будет таймаут и всплывёт модальное окошко, что база не отвечает и надо бы нажать на кнопку продолжить или отключится..

Может, проще создавать ОЛЕ-объект по мере необходимости, и разрушать его, как только необходимость закончилась?

ОЛЕ мне нужен только для того, чтобы полноценно работать с DBF (например, видеть перечисления, которые из DD не увидишь).
Идея ОЛЕ мне кажется слишком громоздкой, лучше бы, конечно прямой доступ (пока реальным считаю только ADODB, но там тоже надо знать структуру полей). Как прочиать MD без OLE?

Я имею ввиду ОЛЕ к специальной базе, в которой есть справочник путей к базам 77, которые будут консолидироваться (до 10 штук). В этой же ОЛЕ будет загружена 1cpp и создан объект MetaDataWork, который даст возможность походить поочередно по вон тем базам (чтобы не создавать ОЛЕ к каждой базе, потому что "скорость ОЛЕ оставляет желать лучшего").
Может можно будет создать ссылку на MetаDataWork в восьмерке (через ОЛЕ к специальной базе), убить ОЛЕ и пользоваться ссылкой?

Лунтик писал(а) 17. Июня 2011 :: 07:34:


Как вариант - иметь некоторые файлы декомпиляции МДшника (правда, нужен будет регламент, который бы поддерживал актуальность этих файлов).
На вскидку - ОбъектыМетаданных.txt, Перечисления.mdp достаточно в довесок к DD/DDS

+ один из последних вариантов того модуля

Функция ЧГ0(ЗначениеЧисло)
	Возврат Формат(ЗначениеЧисло,"ЧГ=0");
КонецФункции

Функция ЗагрузитьМетаданные(КаталогИБ, ИмяПользователяV7, ПарольПользователяV7, ИдентификаторХранилищаМетаданных) Экспорт
	МД = Новый Структура;

	Состояние("Подключение к " + КаталогИБ);

	V7 = Новый COMОбъект("V77.Application");
	Если V7.Initialize(V7.RMTrade, "/d"""+КаталогИБ+""" /n"+ИмяПользователяV7+" /p"+ПарольПользователяV7, "NO_SPASH_SHOW") = 0 Тогда
		Сообщить("Нет доступа к информационной базе.");
		Возврат Ложь;
	КонецЕсли;

	MDW = V7.CreateObject("MetaDataWork");

	MD = V7.Метаданные;

	Состояние("Загрузка справочников..");
	Ст1 = Новый Структура;
	МД.Вставить("Справочник", Ст1);
	Для Номер1 = 1 По MD.Справочник() Цикл
		МДСправочник = MD.Справочник(Номер1);
		Ст2 = Новый Структура;
		Ст1.Вставить(МДСправочник.Идентификатор, Ст2);
		Ст2.Вставить("ИД", ЧГ0(MDW.ИДОбъекта(МДСправочник)));
		Ст2.Вставить("ИД36", Прав(V7.EvalExpr("_idtostr("+ЧГ0(MDW.ИДОбъекта(МДСправочник))+")"),4));
		Для Номер2 = 1 По МДСправочник.Реквизит() Цикл
			МДРеквизит = МДСправочник.Реквизит(Номер2);
			Ст2.Вставить(МДРеквизит.Идентификатор, ЧГ0(MDW.ИДОбъекта(МДРеквизит)));
		КонецЦикла;
	КонецЦикла;

	Состояние("Загрузка перечислений..");
	Ст1 = Новый Структура;
	МД.Вставить("Перечисление", Ст1);
	Для Номер1 = 1 По MD.Перечисление() Цикл
		МДПеречисление = MD.Перечисление(Номер1);
		Ст2 = Новый Структура;
		Ст1.Вставить(МДПеречисление.Идентификатор, Ст2);
		Ст2.Вставить("ИД", ЧГ0(MDW.ИДОбъекта(МДПеречисление)));
		Для Номер2 = 1 По МДПеречисление.Значение() Цикл
			МДЗначение = МДПеречисление.Значение(Номер2);
			Ст2.Вставить(МДЗначение.Идентификатор, V7.EvalExpr("_idtostr("+ЧГ0(MDW.ИДОбъекта(МДЗначение))+")")+"   ");
		КонецЦикла;
	КонецЦикла;

	Состояние("Загрузка граф отбора..");
	Ст1 = Новый Структура;
	МД.Вставить("ГрафаОтбора", Ст1);
	Для Номер1 = 1 По MD.ГрафаОтбора() Цикл
		МДГрафаОтбора = MD.ГрафаОтбора(Номер1);
		Ст2 = Новый Структура;
		Ст1.Вставить(МДГрафаОтбора.Идентификатор, Ст2);
		Ст2.Вставить("ИД", ЧГ0(MDW.ИДОбъекта(МДГрафаОтбора)));
	КонецЦикла;

	Состояние("Загрузка документов..");
	Ст1 = Новый Структура;
	МД.Вставить("Документ", Ст1);
	Для Номер1 = 1 По MD.Документ() Цикл
		МДДокумент = MD.Документ(Номер1);
		Ст2 = Новый Структура;
		Ст1.Вставить(МДДокумент.Идентификатор, Ст2);
		Ст2.Вставить("ИД", ЧГ0(MDW.ИДОбъекта(МДДокумент)));
		Для Номер2 = 1 По МДДокумент.РеквизитШапки() Цикл
			МДРеквизит = МДДокумент.РеквизитШапки(Номер2);
			Ст2.Вставить(МДРеквизит.Идентификатор, ЧГ0(MDW.ИДОбъекта(МДРеквизит)));
		КонецЦикла;
		Для Номер2 = 1 По МДДокумент.РеквизитТабличнойЧасти() Цикл
			МДРеквизит = МДДокумент.РеквизитТабличнойЧасти(Номер2);
			Ст2.Вставить(МДРеквизит.Идентификатор, ЧГ0(MDW.ИДОбъекта(МДРеквизит)));
		КонецЦикла;
	КонецЦикла;

	Состояние("Загрузка регистров..");
	Ст1 = Новый Структура;
	МД.Вставить("Регистр", Ст1);
	Для Номер1 = 1 По MD.Регистр() Цикл
		МДРегистр = MD.Регистр(Номер1);
		Ст2 = Новый Структура;
		Ст1.Вставить(МДРегистр.Идентификатор, Ст2);
		Ст2.Вставить("ИД", ЧГ0(MDW.ИДОбъекта(МДРегистр)));
		Для Номер2 = 1 По МДРегистр.Измерение() Цикл
			МДИзмерение = МДРегистр.Измерение(Номер2);
			Ст2.Вставить(МДИзмерение.Идентификатор, ЧГ0(MDW.ИДОбъекта(МДИзмерение)))
		КонецЦикла;
		Для Номер2 = 1 По МДРегистр.Ресурс() Цикл
			МДРесурс = МДРегистр.Ресурс(Номер2);
			Ст2.Вставить(МДРесурс.Идентификатор, ЧГ0(MDW.ИДОбъекта(МДРесурс)))
		КонецЦикла;
		Для Номер2 = 1 По МДРегистр.Реквизит() Цикл
			МДРеквизит = МДРегистр.Реквизит(Номер2);
			Ст2.Вставить(МДРеквизит.Идентификатор, ЧГ0(MDW.ИДОбъекта(МДРеквизит)))
		КонецЦикла;
	КонецЦикла;

	СсылкаДопИнфо = Справочники.СохраненныеНастройки.НайтиПоРеквизиту("НастраиваемыйОбъект", ИдентификаторХранилищаМетаданных);
	Если СсылкаДопИнфо.Пустая() Тогда
		ОбъектДопИнфо = Справочники.СохраненныеНастройки.СоздатьЭлемент();
		ОбъектДопИнфо.НастраиваемыйОбъект = ИдентификаторХранилищаМетаданных;
		ОбъектДопИнфо.Наименование = ОбъектДопИнфо.НастраиваемыйОбъект;
		ОбъектДопИнфо.ТипНастройки = Перечисления.ТипыНастроек.ПроизвольныеНастройки;
	Иначе
		ОбъектДопИнфо = СсылкаДопИнфо.ПолучитьОбъект();
	КонецЕсли;
	ОбъектДопИнфо.ХранилищеНастроек = Новый ХранилищеЗначения(МД);
	ОбъектДопИнфо.Записать();

	Возврат Истина;
КонецФункции

Функция ПолучитьСтрокой(ЗначениеСтроки) Экспорт
	Если ПустаяСтрока(ЗначениеСтроки) Тогда
		Возврат "";
	ИначеЕсли ЗначениеСтроки = Null Тогда
		Возврат "";
	Иначе
		Возврат СокрП(ЗначениеСтроки);
	КонецЕсли;
КонецФункции

Функция ПолучитьДатой(ЗначениеДаты) Экспорт
	Если ЗначениеДаты = '17530101000000' Тогда
		Возврат '00010101000000';
	ИначеЕсли ЗначениеДаты = Null Тогда
		Возврат '00010101000000';
	Иначе
		Возврат ЗначениеДаты;
	КонецЕсли;
КонецФункции

Функция РасшифроватьДатуВремя(ДатаВремяИД) Экспорт
	ДатаВремя = Дата(Число(Лев(ДатаВремяИД, 4)), Число(Сред(ДатаВремяИД, 5, 2)), Число(Сред(ДатаВремяИД, 7, 2)));

	Вес = 1;
	Секунд=0;
	Для Ном = 0 по 5 Цикл
		Код = КодСимвола(ДатаВремяИД, 14 - Ном);
		Если Код < 65 Тогда
			Код = Код - 48;
		Иначе
			Код = Код - 55;
		КонецЕсли;
		Секунд = Секунд + Код * Вес;
		Вес = Вес * 36;
	КонецЦикла;
	ДатаВремя = ДатаВремя + Секунд / 10000;
	Возврат ДатаВремя;
КонецФункции
 

Лунтик писал(а) 17. Июня 2011 :: 09:55:

Да.
При этом структуры затягивать через ОЛЕ не каждый раз когда захочется с семерошными данными поработать, а по необходимости, например после значимой реструктуризации.

Лунтик писал(а) 23. Июня 2011 :: 06:03:


http://forum.script-coding.com/viewtopic.php?id=2214

и класс, на её основе от chessman

Да. Спасибо.

Добавил инфу в репозиторий.

Лунтик писал(а) 23. Июня 2011 :: 09:18:

http://www.1cpp.ru/forum/YaBB.pl?board=repo