Предлагаю удобный класс Общие.ПомощникСозданияКласса для простого создания классов на лету в режиме работы 1С:Предприятие

// ПомощникСозданияКласса

Перем
		_МетаИнфо,
		_Текст
		;

Процедура Конструктор()
	_МетаИнфо = СоздатьОбъект("MetaInfoClasses");
	_Текст = СоздатьОбъект("Текст");
КонецПроцедуры // Конструктор

Функция ПолучитьСлучайноеИмяНовогоКласса() Экспорт
	Математика = СоздатьОбъект("Математика");
	СлучайноеЧисло = Математика.RAND();

	// использую случайное имя класса, чтобы можно было добавлять,
	// 	иначе будет ошибка повторного определения класса
	ИмяНовогоКласса = "НовыйКласс_"+Строка(СлучайноеЧисло);
	Возврат ИмяНовогоКласса;
КонецФункции

Функция ПолучитьИмяФайлаКласса(НаименованиеНовогоКласса, КаталогФайла)
	Если КаталогФайла = "" Тогда
		ИмяФайлаКласса = НаименованиеНовогоКласса+".txt"; // т.е. в КаталогИБ
	Иначе
		лКаталог = КаталогФайла;
		Если Прав(лКаталог, 1) <> "\" Тогда
			лКаталог = лКаталог + "\";
		КонецЕсли;
		Если Врег(лКаталог) = Врег(КаталогИБ()) Тогда
			лКаталог = "";
		КонецЕсли;

		ИмяФайлаКласса = лКаталог + НаименованиеНовогоКласса+".txt";
		//ИмяФайлаКласса = Симв(34) +ИмяФайлаКласса + Симв(34);
	КонецЕсли;
//Сообщить("ИмяФайлаКласса = <"+ИмяФайлаКласса+">");

	Возврат ИмяФайлаКласса;
КонецФункции

Функция СоздатьФайлНовогоКласса(НаименованиеНовогоКласса, ТекстКласса, КаталогФайла)
	ИмяФайлаКласса = ПолучитьИмяФайлаКласса(НаименованиеНовогоКласса, КаталогФайла);

	_Текст.ДобавитьСтроку(ТекстКласса);
	_Текст.Записать(ИмяФайлаКласса);

	//вирт().ДобавитьВременныйФайл(ИмяФайлаКласса); // TODO пользователь должен самостоятельно удалять файл после использования, если это нужно

	Возврат ИмяФайлаКласса;
КонецФункции

Функция ПолучитьОписаниеНовогоКласса(НаименованиеНовогоКласса, СтрокаНаследников ,ПутьКФайлуКласса)
	лТекстКласса = "class "+НаименованиеНовогоКласса+" = "+ПутьКФайлуКласса;
	Если СокрЛП(СтрокаНаследников) <> "" Тогда
		лТекстКласса = лТекстКласса +" : "+СтрокаНаследников;
	КонецЕсли;

	Возврат лТекстКласса + "
		|{
		|}";
КонецФункции

Функция СоздатьНовыйКласс(ИмяНовогоКласса, ТекстКласса, СтрокаНаследников, КаталогФайла = "") Экспорт
	фНельзяСоздавать = 0;
	Попытка
		лНовыйОбъект = СоздатьОбъект(ИмяНовогоКласса);
		фНельзяСоздавать = 1;
	Исключение
	КонецПопытки;

	Если фНельзяСоздавать = 1 Тогда
		вирт()._ВыброситьИскл("Класс "+ИмяНовогоКласса+" уже существует");
	КонецЕсли;

	лТекстКласса = ТекстКласса;
	Если СокрЛП(лТекстКласса) = "" Тогда
		лТекстКласса = "//"; // пустых классов не бывает !
	КонецЕсли;

	лИмяФайла = СоздатьФайлНовогоКласса(ИмяНовогоКласса, лТекстКласса, КаталогФайла);
	СтрокаОписанияКласса = ПолучитьОписаниеНовогоКласса(ИмяНовогоКласса, СтрокаНаследников, лИмяФайла);

	_МетаИнфо.ЗагрузитьОписаниеКлассов(СтрокаОписанияКласса);

	Возврат лИмяФайла;
КонецФункции 

Класс успешно прошел тестирование и активно используется в конфигурации тестирования 1С++.

AndreyM писал(а) 11. Августа 2008 :: 11:25:


1. Да, интересно.
2. А зачем тогда: ПолучитьСлучайноеИмяНовогоКласса() ?

Возможно, замена Вып. модуля., создание динамического класса?

artbear писал(а) 11. Августа 2008 :: 11:44:

Удалось найти отличное боевое применение
Использовал данный класс в разработке "Набор классов для универсального перехвата событий" http://www.1cpp.ru/forum/YaBB.pl?num=1218783847/0

С помощью класса генерю спец.класс для возможности перехвата любых событий формы на лету в любой момент времени.
Получилось очень удобно и просто расширяемо - пользователь предварительно задает параметры всех/нужных событий формы (имя и кол-во параметров - например, ПослеЗакрытия, 0 ), а разработка автоматически генерит класс со обработчиками для всех указанных событий формы и выполняет перехват этих событий.

Т.е. сфера применения класса - это генерация класса на лету в зависимости от некоторых условий.

ЗЫ постараюсь сегодня доработать указанную разработку в т.ч. для аналогичного перехвата событий ГМ.
Потом выложу в соответствующую ветку.