Планируется перевод базы на SQL, вот и решил затестить.
Суть: есть такая конструкция, кторая выводит в ТЗ на форме остатки по текущему товару в разрезе подразделений:
     ТЗ_Наличие.УдалитьСтроки();
     Для Н=1 По СпПодр.РазмерСписка() Цикл
           Подр=СпПодр.ПолучитьЗначение(Н,);
           Кол=РегОТ.СводныйОстаток(Подр,ВыбНоменклатура,,"Количество");
           МинОстаток = ВыбНоменклатура.МинимальныйОстаток; 
           КонтрольМинОстатка = Подр.КонтрольМинОстатка;
           Разница = 0;
           Если (КонтрольМинОстатка = 1) И (МинОстаток <> 0) Тогда
                 Разница = Кол - МинОстаток;
           КонецЕсли;      
           Если Кол<>0 Тогда
                 ТЗ_Наличие.НоваяСтрока();
                 ТЗ_Наличие.Склад=Подр;
                 ТЗ_Наличие.Количество=Кол;
                 Если Разница < 0 Тогда
                       ТЗ_Наличие.Пикт = 35;
                 КонецЕсли;      
           КонецЕсли;
     КонецЦикла;

Пытаюсь этот код переложить на прямой запрос следующим образом:
     ТекстЗапроса = "
     |Select
     |    Номенклатура [Товар $Справочник.Номенклатура],
     |    Подразделение [Склад $Справочник.Подразделения], 
     |    КоличествоОстаток ОстатокТовара
     |FROM
     |    $РегистрОстатки.Склад(
     |      ,
     |      ,
     |      (Номенклатура = :ВыбНоменклатура) And Подразделение in (Select val from #ВыбСклад),
     |      (Подразделение, Номенклатура),
     |      Количество
     |      ) остатки
     |";
     Запрос.УложитьСписокОбъектов(спПодр,"#ВыбСклад","Подразделения");
     Запрос.УстановитьТекстовыйПараметр("ВыбНоменклатура", ВыбНоменклатура);
     ТЗ = Запрос.ВыполнитьИнструкцию(ТекстЗапроса);
     ТЗ_Наличие.УдалитьСтроки();
     Для Н=1 По ТЗ.КоличествоСтрок() Цикл
           ТЗ.ПолучитьСтрокуПоНомеру(Н);
           Кол  = ТЗ.ОстатокТовара;
           Подр = ТЗ.Склад;
           МинОстаток = ВыбНоменклатура.МинимальныйОстаток; 
           КонтрольМинОстатка = Подр.КонтрольМинОстатка;
           Разница = 0;
           Если (КонтрольМинОстатка = 1) И (МинОстаток <> 0) Тогда
                 Разница = Кол - МинОстаток;
           КонецЕсли;      
           Если Кол<>0 Тогда
                 ТЗ_Наличие.НоваяСтрока();
                 ТЗ_Наличие.Склад=Подр;
                 ТЗ_Наличие.Количество=Кол;
                 Если Разница < 0 Тогда
                       ТЗ_Наличие.Пикт = 35;
                 КонецЕсли;      
           КонецЕсли;
     КонецЦикла;
... и получаю, что штатное средство работает быстрее, нежели прямой запрос.
Отсюда вопросы:
1.  Всегда ли целесообразно использовать прямые запросы? Или в отдельных случаях необходимо обходиться штатными средствами 1С?

berezdetsky писал(а) 27. Марта 2008 :: 07:33:

+1
На всякий случай: а разве дату получения остатка не нужно указывать ?

artbear писал(а) 27. Марта 2008 :: 07:38:

Если дата не указана, остатки считаются на ТА.

Как-то так:

|Select
|    Номенклатура [Товар $Справочник.Номенклатура],
|    Подразделение [Склад $Справочник.Подразделения],
|    КоличествоОстаток ОстатокТовара,
|    CASE WHEN ($Подразделения.КонтрольМинОстатка = 1) AND ($Номенклатура.МинимальныйОстаток <> 0)
|	  THEN (остатки.КоличествоОстаток - $Номенклатура.МинимальныйОстаток)
|	  ELSE 0
|    END Разница
|FROM
|    $РегистрОстатки.Склад(,,
|	  (Номенклатура = :ВыбНоменклатура) And Подразделение in (Select val from #ВыбСклад),
|	  (Подразделение, Номенклатура),
|	  Количество
|    ) остатки
|    INNER JOIN $Справочник.Подразделения AS Подразделения (nolock) ON остатки.Подразделение = Подразделения.ID
|    INNER JOIN $Справочник.Номенклатура AS Номенклатура (nolock) ON остатки.Номенклатура = Номенклатура.ID  

А если абсолютное значение разницы не нужно, то

|    CASE WHEN ($Подразделения.КонтрольМинОстатка = 1) AND (остатки.КоличествоОстаток < $Номенклатура.МинимальныйОстаток)
|	  THEN 35
|	  ELSE  0
|    END Пикт 

leshik писал(а) 27. Марта 2008 :: 08:51:

Там экономия на времени компиляции, а не на времени выполнения. Если в #0 речь идёт о форме списка, конечно, подготовленный запрос или RPCMode будет полезно.

А как же
Подразделение in (Select val from #ВыбСклад)
?  Ты теперь и подразделения в цикле перебираешь? Верни как было и заполняй #ВыбСклад один раз при открытии формы списка.
И пробуй для начала не подготовленные запросы, а RPCMode - оно проще в использовании.

berezdetsky писал(а) 27. Марта 2008 :: 10:12:


Вот так все работает:

	ТекстЗапроса = "
	|Select
	|    Номенклатура [Товар $Справочник.Номенклатура],
	|    Подразделение [Склад $Справочник.Подразделения],
	|    КоличествоОстаток ОстатокТовара,
	|    CASE WHEN ($Подразделения.КонтрольМинОстатка = 1) AND (остатки.КоличествоОстаток < $Номенклатура.МинимальныйОстаток)
	|	  THEN 35
	|	  ELSE  0
	|    END Пикт
	|FROM
	|    $РегистрОстатки.Склад(,,
	|	  (Номенклатура = :ВыбНоменклатура) And Подразделение in (Select val from #ВыбСклад),
	|	  (Подразделение, Номенклатура),
	|	  Количество
	|    ) остатки
	|    INNER JOIN $Справочник.Подразделения AS Подразделения (nolock) ON остатки.Подразделение = Подразделения.ID
	|    INNER JOIN $Справочник.Номенклатура AS Номенклатура (nolock) ON остатки.Номенклатура = Номенклатура.ID
	|";

	Запрос.УложитьСписокОбъектов(спПодр,"#ВыбСклад","Подразделения");
	Запрос.УстановитьТекстовыйПараметр("ВыбНоменклатура", ВыбНоменклатура);
	Запрос.РежимRPC(1);
	ТЗ = Запрос.ВыполнитьИнструкцию(ТекстЗапроса);
	ТЗ_Наличие.УдалитьСтроки();
	ТЗ.ВыбратьСтроки();
	Пока ТЗ.ПолучитьСтроку() = 1 Цикл
			ТЗ_Наличие.НоваяСтрока();
			ТЗ_Наличие.Склад = ТЗ.Склад;
			ТЗ_Наличие.Количество = ТЗ.ОстатокТовара;
			ТЗ_Наличие.Пикт = ТЗ.Пикт;
	КонецЦикла;
 

спПодр - это список Подразделений, который заполняется в ПриОткрытии
ВыбНоменклатура - пока только реквизит на тестовой обработке.

Но замеры показывают, что это в 2 раза медленее, чем штатно как в 0. Как ускорить? Есть ли такая возможность, или нет?

berezdetsky писал(а) 27. Марта 2008 :: 10:39:



Запрос.УложитьСписокОбъектов(спПодр,"#ВыбСклад","Подразделения");
перенес в ПриОткрытии, эффект следующий: если первый раз выполнить прямой запрос, то он по времени несколько дольше, чем штатно, а затем в 3 раза быстрее. С чем это связано?
ТЗ_Наличие нужна для пост обработки, т. к. там еще должен отображаться резерв и при необходимости его расшифровка.

Товар действительно не нужен - убрал.

ОГРОМНОЕ ТЕБЕ СПАСИБО. Только из одной ветки с твоей помощю узнал много больше, чем из доки.