В общем делаю что-то типа графа подчинённости документа. Сначала попробывал поюзать майкрософтовское дерево. Всё получилось, делал примерно вот так:

Процедура Сформировать(Корень, ТекДок)
	Док = СоздатьОбъект("Документ");
	Док.ВыбратьПодчиненныеДокументы(,,ТекДок);

	Пока Док.ПолучитьДокумент() = 1 Цикл
		Ключ=Ключ+1;	  
		Узел=Дерево.Объект.Nodes.Add(Корень,4, Строка(Док)+Ключ ,Строка(Док));
		Узел.Tag=ЗначениеВСтрокуВнутр(Док.ТекущийДокумент());
		Если ТекУровеньВложенности<УровеньВложенности Тогда
			ТекУровеньВложенности=ТекУровеньВложенности+1;
			Сформировать(Узел, Док);
		КонецЕсли;
	КонецЦикла;

	ТекУровеньВложенности = ТекУровеньВложенности - 1;
КонецПроцедуры  

"УровеньВложенности" - переменная в которой хранится уровень, до которого надо опускаться при построении дерева подчинённости.
Но из-за ограниченности майкрософтовского дерева, решил использовать дерево АЛьФа. Но теперь я не пойму как рекурсивно добовлять узлы.

Создал такую ТЗ:

ФДеревоТЗ.НоваяКолонка("Ветка", "ТаблицаЗначений");
	ФДеревоТЗ.НоваяКолонка("Картинка");
	ФДеревоТЗ.НоваяКолонка("НазваниеВетки",,,,"Документ");
	ФДеревоТЗ.НоваяКолонка("НомерПолиса");
	СтруктураТЗ = ЗначениеВСтрокуВнутр(ФДеревоТЗ); 

Я понимаю, что можно писать примерно так:

ФДеревоТЗ.Ветка.Ветка =  //для второго уровня
ФДеревоТЗ.Ветка.Ветка.Ветка =  //для третьего уровня
.... 

Но как это засунуть в рекурсию? Помогите сообразить...

Функция НайтиКорень(Док)
	мдДок=Метаданные.Документ(Док.Вид()); КореньДок="";
	Для ъ=1 По мдДок.РеквизитШапки() Цикл
		текОбъект=Док.ПолучитьАтрибут(мдДок.РеквизитШапки(ъ));
		Если (ТипЗначенияСтр(текОбъект)="Документ") И (ПустоеЗначение(текОбъект)=0) Тогда
			//*** Если Метаданные.Документ(текОбъект.Вид()).Синоним="Служебный документ" Тогда Продолжить; КонецЕсли; //Заглушка
			Если ВыбДокумент=текОбъект Тогда Продолжить; КонецЕсли; КореньДок=текОбъект; Прервать;
		КонецЕсли;
	КонецЦикла;
	Возврат ?(ПустоеЗначение(КореньДок)=1, Док, НайтиКорень(КореньДок));
КонецФункции
//--------------------------------------------

Процедура СформироватьДеревоПодчиненныхДокументов(тзДерево, Док)
	ДокПодч=СоздатьОбъект("Документ");
	Если ДокПодч.ВыбратьПодчиненныеДокументы(,, Док)=0 Тогда Возврат; КонецЕсли;
	Пока ДокПодч.ПолучитьДокумент()=1 Цикл
		текДок=ДокПодч.ТекущийДокумент();

		тзДерево.НоваяСтрока();
		тзДерево.Пиктограмма=ПолучитьПиктограммуДоумента(текДок);
		тзДерево.Док=текДок;
		тзДерево.Представление=ПредставлениеДокумента(текДок);
		тзДерево.тзВетка=_Новый("ТаблицаЗначений");
		тзДерево.тзВетка.Загрузить(тзДеревоПодчиненностиШаблон);
		тзДеревоПодчиненности.ВидимостьКолонки("Док", 0);

		СформироватьДеревоПодчиненныхДокументов(тзДерево.тзВетка, текДок);
	КонецЦикла;
КонецПроцедуры
//--------------------------------------------

Процедура тзДеревоПодчиненности_ВыполнитьДействие(стрДействие)
	Если стрДействие="Обновить" Тогда
		Если ВыбДокумент.Выбран()=0 Тогда Возврат; КонецЕсли;
		КореньДок=НайтиКорень(ВыбДокумент);

		тзДеревоПодчиненности.УдалитьСтроки();
		тзДеревоПодчиненности.НоваяСтрока();
		тзДеревоПодчиненности.Пиктограмма=ПолучитьПиктограммуДоумента(КореньДок);
		тзДеревоПодчиненности.Док=КореньДок;
		тзДеревоПодчиненности.Представление=ПредставлениеДокумента(КореньДок);
		тзДеревоПодчиненности.тзВетка=_Новый("ТаблицаЗначений");
		тзДеревоПодчиненности.тзВетка.Загрузить(тзДеревоПодчиненностиШаблон);
		тзДеревоПодчиненности.ВидимостьКолонки("Док", 0);

		СформироватьДеревоПодчиненныхДокументов(тзДеревоПодчиненности.тзВетка, КореньДок);

		дзДеревоПодчиненности.ОбновитьДерево();
	КонецЕсли;
КонецПроцедуры
//--------------------------------------------

тзДеревоПодчиненности.НоваяКолонка("тзВетка", "ТаблицаЗначений");
тзДеревоПодчиненности.НоваяКолонка("Пиктограмма", "Число",,, "", 4);
тзДеревоПодчиненности.НоваяКолонка("Представление", "Строка",,, "Документ", 30);
тзДеревоПодчиненности.НоваяКолонка("Док", "Документ",,, "Документ 1", 100);
тзДеревоПодчиненности.ВидимостьКолонки("Док", 0);

тзДеревоПодчиненностиШаблон=_Новый("ТаблицаЗначений");
тзДеревоПодчиненностиШаблон.Загрузить(тзДеревоПодчиненности);
 

если я правильно понял конечно...

trdm писал(а) 19. Апреля 2007 :: 14:20:

Если там, где прямыми запросами, то там сделано через объект "таблица", а мне надо "реальное" дерево.

noprogrammer писал(а) 19. Апреля 2007 :: 14:28:

Буду благодарен.
А что за функция "_Новый"?

noprogrammer писал(а) 19. Апреля 2007 :: 17:51:

Спасибо!
Вчера, наверное, был вечерний тупняк. При создании графа в дереве от MS, я в рекурсивную процедуру передавал текущий узел, а вот чё-т в случае с ТЗ тормознул... оказывается всё просто - передавай "тзДерево.тзВетка"