Всем привет!
Может подскажет кто, есть ли описалово+примеры по работе в 1С 8 через ОЛЕ?

А что нужно работа 1с8 как сервера автоматизации или обращение из 1с8 к другим программам?

Вот пример из книги Михайлова "1С:Предприятие 7.7/8.0 Системное программирование"

objIE = New ComObject("InternetExplorer.Application");
objIE.Visible = Ложь; //Отключаем видимость
objIE.Silent = Ложь;
objIE.Navigate(Адрес);
Сообщить("Идет загрузка страницы. Ждите...");
Пока objIE.readyState<4 Цикл // Ждем пока загрузится страница
КонецЦикла;
objDoc = objIE.Document;
Для Каждого a Из objDoc.all.Tags("A") Цикл //Перебираем все ссылки  
    Сообщить(a.href);
КонецЦикла;
objIE.Quit(); //Закрываем приложение
objIE = Неопределено;
 

Alex_Bob писал(а) 07. Октября 2008 :: 11:33:


я всё таки обращу внимание на web-службы - пример взаимодействия чистой воды

Цитата:

Пример

 V77 = Новый COMОбъект("V77M.Application");

	Если  V77.Initialize(V77.RMTrade,"ИсточникСтр","") Тогда
	       Сообщить("Успех");
		   ЗаполнитьОснованиеРеализации(V77);

	Иначе  Предупреждение("Ошибка открытия информационной базы");
           Возврат;

	КонецЕсли;
 

Процедура ЗаполнитьОснованиеРеализации(V77)
	 Накл= V77.EvalExpr("CreateObject(""Документ.РасходнаяНакладная"")");
	 ДокОсн= V77.EvalExpr("CreateObject(""Документ"")");

	 Накл.ВыбратьДокументы();
	 Пока Накл.ПолучитьДокумент()=1 Цикл
		 Номер=СокрЛП(Накл.НомерДок);
		  ДокСоотв=Документы.РеализацияТоваров.НайтиПоНомеру(СокрЛП(Номер), Накл.ДатаДок);  
		   Если Накл.Проведен()=0 Тогда
		     Продолжить;

		 КонецЕсли;
        Если ДокСоотв=Документы.РеализацияТоваров.ПустаяСсылка() Тогда  
	         Сообщить("! для "+Накл.Вид()+" "+Накл.НомерДок+" не найдено соответстствие");
             Продолжить;

		 КонецЕсли;
		Если Накл.ДокументОснование.Выбран()=0 Тогда
			Продолжить;
		КонецЕсли;
// и т.д.
 

Самое быстрое через ADO, например к ДБФ

ADO= Новый COMОбъект( "ADODB.Connection" );
ADO.Open("
    |Provider=VFPOLEDB.1;
    |Deleted=Yes;
    |Null = Yes;
    |Exclusive = No;
    |SourceType = DBF;
    |Data Source=" + КаталогИБСтрокой + ";
    |Mode=ReadWrite;
    |Extended Properties="""";
    |User ID="""";
    |Password="""";
    |Mask Password=False;
    |Collating Sequence=MACHINE;
    |DSN="""""); 

и далее как Fez описывал.
Запрос можно подготовить с помощью 1С++
(Писать с использованием $, далее через Отладка(1) получить реальные имена таблиц и этот запрос использовать в ADO)

Я в шоке!

	V7 = Новый ComОбъект("V77s.Application");
    Открыта = V7.Initialize(V7.RMTrade,"/d\\d2enkor\Work_2008","NO_SPLASH_SHOW");
	Если Открыта Тогда
		Запрос = V7.CreateObject("OdbcRecordSet");
		ТЗ = "
		|select СпрТ.id [Элем $Справочник.Города]
		|from $Справочник.Города СпрТ (nolock)
		|where СпрТ.isMark = 0";
		ТЗн = Запрос.ВыполнитьИнструкцию(ТЗ);
		ТЗн.ВыбратьСтроки();
		Пока ТЗн.ПолучитьСтроку()= 1 Цикл
			Сообщить(ТЗн.Элем.Наименование+" "+Формат(Тзн.Элем.Код, "Ч(0)9.0"))
		КонецЦикла
	КонецЕсли;

 

Работает!!!!!!

Цитата:

Вот я про это и написал

kiruha писал(а) 08. Октября 2008 :: 09:45:

		Запрос = V7.CreateObject("OdbcRecordSet");
		VT = V7.CreateObject("Addin.ValTable");
ТЗ = "
		|select СпрТ.id [Элем $Справочник.Города]
		|from $Справочник.Города СпрТ (nolock)
		|where СпрТ.isMark = 0";
				 VT.Загрузить(Запрос.ВыполнитьИнструкцию(ТЗ));
			Тзн = VT.ПолучитьИтоги("Элем","");		Тзн.ВыбратьСтроки();
		Пока Тзн.ПолучитьСтроку()= 1 Цикл
			Сообщить(Тзн.Элем.Наименование+" "+Формат(Число(Тзн.Элем.Код), "ЧЦ=9;ЦДЦ=0;ЧН=0;"))
		КонецЦикла
 

И группируй как хочешь, думаю, что и ИТЗ сработает.
Только что-то Формат(Число(Тзн.Элем.Код), "ЧЦ=9;ЦДЦ=0;ЧН=0;"))
не пашет, мне надо чтобы было "00000000234", а выводит "234".

artbear писал(а) 08. Октября 2008 :: 10:35:


Да.
Но все таки решил проверить и провел тест

перем  V7,локОлеДБКоманда,локОлеДБ;
Процедура КнопкаВыполнитьНажатие(Кнопка)
			ТекстЗапроса = "
		|select СпрТ.id as id
		|from $Справочник.Номенклатура as СпрТ
		|";
		ТЗн = локОлеДБКоманда.ВыполнитьИнструкцию(ТекстЗапроса);
		ТЗн.ВыбратьСтроки();

		Пока ТЗн.ПолучитьСтроку()= 1 Цикл
			 id=ТЗн.id;

		КонецЦикла ;


КонецПроцедуры
 

Последняя колонка - это процент общего времени выполнения
Цитата:


Обращение к свойствам com-объекта ТЗн занимают в сумме 96%
Собственно запрос 3.5% от общего времени
Если бы было 10 полей, что достаточно типично,
то собственно запрос наверно займет 1/300 от общего времени выполнения

Здесь Dmitro писал специальную компоненту
GameWithFire
для быстрой загрузки в ТЗ из ADO.
правда от 13 2007

Alex_Bob писал(а) 09. Октября 2008 :: 13:38:


Примерчик?

Цитата:

Поищи на форуме itland или на этом форуме по названию ВК.

Я решал такую задачу (регулярный перенос данных из 77 в 8).
Сделал так: из 8ки прямыми запросами к бд 77 через ADO.
Для быстрого и удобного получения результата прямого запроса использовал ранее написанную ради шутки GameWithFire, немного доработал ее, чтобы получать не только объект ТаблицаЗначений, а сразу объект РезультатЗапроса.

По поводу проблемы имен объектов базы 77.
Текст запроса собирается конкатенацией. Конфигурацию 8ки научил получать и хранить сведения о метаданных, именах объектов БД, идентификаторах.
Хранится все в виде вложенных объектов типа Структура. Текст запроса писать достаточно удобно.
Получение (или обновление) информации о метаданных 77 идет подключением к ИБ 77 по ОЛЕ и использованием 1с++ (MetaDataWork) для получения внутренних идентификаторов.

Вроде все просто.

DmitrO писал(а) 12. Октября 2008 :: 06:08:


А можно посмотреть пример реализации этого механизма (обработку), именно с использованием GameWithFire?

По просьбам трудящихся, процедура, которая формирует объект Структура, содержащая метаданные 77 для составления прямых запросов.

Функция ЗагрузитьМетаданные(КаталогИБ, ИмяПользователяV7, ПарольПользователяV7) Экспорт
	МД = Новый Структура;

	Состояние("Подключение к " + КаталогИБ);

	V7 = Новый COMОбъект("V77.Application");
	Если V7.Initialize(V7.RMTrade, "/d"""+КаталогИБ+""" /n"+ИмяПользователяV7+" /p"+ПарольПользователяV7, "NO_SPASH_SHOW") = 0 Тогда
		Сообщить("Нет доступа к информационной базе.");
		Возврат Ложь;
	КонецЕсли;

	MDW = V7.CreateObject("MetaDataWork");

	MD = V7.Метаданные;

	Состояние("Загрузка справочников..");
	Ст1 = Новый Структура;
	МД.Вставить("Справочник", Ст1);
	Для Номер1 = 1 По MD.Справочник() Цикл
		МДСправочник = MD.Справочник(Номер1);
		Ст2 = Новый Структура;
		Ст1.Вставить(МДСправочник.Идентификатор, Ст2);
		Ст2.Вставить("ИД", MDW.ИДОбъекта(МДСправочник));
		Для Номер2 = 1 По МДСправочник.Реквизит() Цикл
			МДРеквизит = МДСправочник.Реквизит(Номер2);
			Ст2.Вставить(МДРеквизит.Идентификатор, MDW.ИДОбъекта(МДРеквизит));
		КонецЦикла;
	КонецЦикла;

	Состояние("Загрузка перечислений..");
	Ст1 = Новый Структура;
	МД.Вставить("Перечисление", Ст1);
	Для Номер1 = 1 По MD.Перечисление() Цикл
		МДПеречисление = MD.Перечисление(Номер1);
		Ст2 = Новый Структура;
		Ст1.Вставить(МДПеречисление.Идентификатор, Ст2);
		Ст2.Вставить("ИД", MDW.ИДОбъекта(МДПеречисление));
		Для Номер2 = 1 По МДПеречисление.Значение() Цикл
			МДЗначение = МДПеречисление.Значение(Номер2);
			Ст2.Вставить(МДЗначение.Идентификатор, V7.EvalExpr("_idtostr("+MDW.ИДОбъекта(МДЗначение)+")")+"   ");
		КонецЦикла;
	КонецЦикла;

	Состояние("Загрузка документов..");
	Ст1 = Новый Структура;
	МД.Вставить("Документ", Ст1);
	Для Номер1 = 1 По MD.Документ() Цикл
		МДДокумент = MD.Документ(Номер1);
		Ст2 = Новый Структура;
		Ст1.Вставить(МДДокумент.Идентификатор, Ст2);
		Ст2.Вставить("ИД", MDW.ИДОбъекта(МДДокумент));
		Для Номер2 = 1 По МДДокумент.РеквизитШапки() Цикл
			МДРеквизит = МДДокумент.РеквизитШапки(Номер2);
			Ст2.Вставить(МДРеквизит.Идентификатор, MDW.ИДОбъекта(МДРеквизит));
		КонецЦикла;
		Для Номер2 = 1 По МДДокумент.РеквизитТабличнойЧасти() Цикл
			МДРеквизит = МДДокумент.РеквизитТабличнойЧасти(Номер2);
			Ст2.Вставить(МДРеквизит.Идентификатор, MDW.ИДОбъекта(МДРеквизит));
		КонецЦикла;
	КонецЦикла;

	Состояние("Загрузка регистров..");
	Ст1 = Новый Структура;
	МД.Вставить("Регистр", Ст1);
	Для Номер1 = 1 По MD.Регистр() Цикл
		МДРегистр = MD.Регистр(Номер1);
		Ст2 = Новый Структура;
		Ст1.Вставить(МДРегистр.Идентификатор, Ст2);
		Ст2.Вставить("ИД", MDW.ИДОбъекта(МДРегистр));
		Для Номер2 = 1 По МДРегистр.Измерение() Цикл
			МДИзмерение = МДРегистр.Измерение(Номер2);
			Ст2.Вставить(МДИзмерение.Идентификатор, MDW.ИДОбъекта(МДИзмерение));
		КонецЦикла;
		Для Номер2 = 1 По МДРегистр.Ресурс() Цикл
			МДРесурс = МДРегистр.Ресурс(Номер2);
			Ст2.Вставить(МДРесурс.Идентификатор, MDW.ИДОбъекта(МДРесурс));
		КонецЦикла;
		Для Номер2 = 1 По МДРегистр.Реквизит() Цикл
			МДРеквизит = МДРегистр.Реквизит(Номер2);
			Ст2.Вставить(МДРеквизит.Идентификатор, MDW.ИДОбъекта(МДРеквизит));
		КонецЦикла;
	КонецЦикла;

	Константы.МетаданныеУдаленнойИБ.Установить(Новый ХранилищеЗначения(МД));
	Возврат Истина;
КонецФункции
 

Формируется конечно не быстро, но Структура - объект сериализуемый, поэтому ее надо просто хранить в ХранилищеЗначения в базе 8ки, и восстанавливать перед каждым переносом данных, а не формировать заново. Обновлять ее можно периодически при изменении конфигурации, ито если изменения влияют на перенос данных.

Обратите внимание: все идентификаторы объектов в 10ой системе, а идентификаторы значений перечислений в 36ой.

DmitrO: Идея отличная. Я уже долгое время ищу способ создания "файловой помойки", т.е консолидации основных данных из баз 7.7 в базе 8.1. Перепробовал кучу способов..  

А только с помощью 1с++ нельзя получить данные? почему-то библиотека в восьмерке не грузится.

Цитата:

Я про 1с++ библиотеку, а не про GameWithFire 

Может кто поможет написать прямой запрос для получения плана счетов (код счета и наименование его видов субконто). Не могу таблицу видов субконто найти...

RomDron писал(а) 29. Октября 2008 :: 15:36:


Видно никто с видами субконто не работал?!!!